计算机等级考试三级含金量_计算机等级考试三级PC上级题精选31-35

【shitiku.jxxyjl.com--等级考试】

上机题之31
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 内存中连续存放着二十个
;*  十进制数的ASCII字符，把它们转换成压缩型(组合型)BCD码。
;*      例如:
;*      内存中有
;*      31H("1"),32H("2"),33H("3"),34H("4") ...(共二十个字节)
;*      结果为   21H,43H, ... (共十个字节)
;*     部分程序已给出，其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中。 运算结果要求从RESULT开始存
;*  放, 由过程SAVE保存到文件OUTPUT1.DAT中。填空BEGIN和END之间
;*  已给出的源程序使其完整(空白已用横线标出，每行空白一般只需
;*  一条指令，但采用功能相当的多条指令亦可)，或删除BEGIN和END
;*  之间原有的代码并自行编程来完成要求的功能。
;*      对程序必须进行汇编, 并与IO.OBJ链接产生PROG1.EXE执行文
;*  件，最终运行程序产生结果 (无结果或结果不正确者均不得分)。
;*  调试中若发现整个程序中存在错误之处，请加以修改。

          EXTRN      LOAD:FAR,SAVE:FAR
N         EQU         10
STAC      SEGMENT   STACK
           DB          128 DUP (?)
STAC      ENDS
DATA     SEGMENT
SOURCE   DB          N*2 DUP(?)
RESULT   DB          N DUP(0)
NAME0    DB          "INPUT1.DAT",0
NAME1    DB          "OUTPUT1.DAT",0
DATA     ENDS
CODE     SEGMENT
           ASSUME    CS:CODE,DS:DATA,SS:STAC
START     PROC       FAR
           PUSH       DS
           XOR        AX,AX
           PUSH       AX
           MOV        AX,DATA
           MOV        DS,AX
           MOV        ES,AX
           LEA        DX,SOURCE        ; 数据区起始地址
           LEA        SI,NAME0         ; 原始数据文件名
           MOV        CX,N*2           ; 字节数
           CALL       LOAD             ; 从"INPUT.DAT"中读取数据
;  **** BEGIN ****
           LEA        SI,SOURCE
           LEA        DI,RESULT
           MOV        CX,N
           CLD
NEXT:      lodsb
          ;LODS__
           and        al,0fh
          ;AND        AL, ____
           MOV        BL,AL
           lodsb
          ;LODS__
           push       cx
           mov        cl,4
          ;PUSH       ____
          ;MOV        CL, ____
           SAL        AL,CL
           pop        cx
          ;POP         ____
           add        al,bl
           stosb
          ;ADD        AL, ____
          ;STOS__
           LOOP       NEXT
           ;  ****  END  ****
           LEA        DX,RESULT         ; 结果数据区首址
           LEA        SI,NAME1          ; 结果文件名
           MOV        CX,N              ; 结果字节数
           CALL       SAVE              ; 保存结果到文件
           RET
START    ENDP
CODE     ENDS
         END        START

input1.dat 内容如下：
30 39 32 39 34 35 30 35 39 33 38 35 36 39 34 32 33 31 36 37
output1.dat 内容应当如下：
90 92 54 50 39 58 96 24 13 76

上机题之32
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是:
;*      对内存中存放的四组带符号8位二进制数(每组由五个数组成,均
;*  不为零)进行处理。处理方法为:当每组中负数多于正数时,将组内正
;*  数变成负数(但绝对值不变,下同),组内负数不变。反之,将组内负数
;*  变成正数,组内正数不变。变换好的数按原序存放在内存中。
;*      例如:
;*      内存中有 FDH,FEH,02H,01H,03H,03H,01H,FFH,FEH,FDH,…
;*  (共四组20个数)
;*      结果为   03H,02H,02H,01H,03H,FDH,FFH,FFH,FEH,FDH,…
;*  (共20个数)
;*      部分程序已给出, 其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中。运算结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已给出的源程序使其完整(空白已用横线标
;*  出,每行空白一般只需一条指令, 但采用功能相当的多条指令亦可),
;*  或删除BEGIN和END之间原有的代码并自行编程来完成要求的功能。
;*      对程序必须进行汇编,并与IO.OBJ链接产生PROG1.EXE执行文件,
;*  最终运行程序产生结果(无结果或结果不正确者均不得分)。调试中
;*  若发现整个程序中存在错误之处, 请加以修改。

           EXTRN      LOAD:FAR,SAVE:FAR
N          EQU        20
STAC       SEGMENT    STACK
           DB         128 DUP (?)
STAC       ENDS
DATA       SEGMENT
SOURCE     DB         N DUP(?)
RESULT     DB         N DUP(0)
NAME0      DB         "INPUT1.DAT",0
NAME1      DB         "OUTPUT1.DAT",0
DATA       ENDS
CODE       SEGMENT
           ASSUME     CS:CODE, DS:DATA, SS:STAC
START      PROC       FAR
           PUSH       DS
           XOR        AX,AX
           PUSH       AX
           MOV        AX,DATA
           MOV        DS,AX
           LEA        DX,SOURCE         ; 数据区起始地址
           LEA        SI,NAME0          ; 原始数据文件名
           MOV        CX,N              ; 字节数
           CALL       LOAD              ; 从 "INPUT1.DAT"中读取数据
;  **** BEGIN ****
           MOV        SI,0
           MOV        DI,0
           mov        bx,4
          ;MOV        BX,___
REPT1:     MOV        DX,0
           MOV        CX,5
CAMP:      MOV        AL,SOURCE[SI]
           INC        SI
           CMP        AL,0
           jl         cont
           jmp        next
          ;___        CONT
          ;JMP        ____
CONT:      INC        DX
NEXT:      LOOP       CAMP
           SUB        SI,5
           MOV        CX,5
           CMP        DX,3
           jge        neg1
          ;___        NEG1
           JMP        NEXT1
NEG1:      MOV        AL,SOURCE[SI]
           INC        SI
           CMP        AL,0
           JG         NEG2
           JMP        NOTNEG
NEG2:      NEG        AL
NOTNEG:    MOV        RESULT[DI],AL
           INC        DI
           LOOP       NEG1
           JMP        NEXT2
NEXT1:     MOV        AL,SOURCE[SI]
           INC        SI
           cmp        al,0
          ;CMP        AL,___
           JL         NEG3
           jmp        notneg1
          ;JMP        _______
NEG3:      NEG        AL
NOTNEG1:   MOV        RESULT[DI],AL
           INC        DI
           LOOP       NEXT1
NEXT2:     DEC        BX
           jz         exit
           ;________________
           JMP        REPT1
EXIT:      NOP
;  ****  END  ****
           LEA        DX,RESULT          ; 结果数据区首址
           LEA        SI,NAME1           ; 结果文件名
           MOV        CX,N               ; 结果字节数
           CALL       SAVE               ; 保存结果到文件
           RET
START      ENDP
CODE       ENDS
           END        START

input1.dat 内容如下：
03 01 02 03 04 03 01 FF FE FD FD FE 02 01 03 FF FE FD FC FB
output1.dat 内容应当如下：
03 01 02 03 04 FD FF FF FE FD 03 02 02 01 03 FF
FE FD FC FB

上机题之33
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 在递增的有序字节数组中
;*  插入一个正整数,  并按指定的数组个数存入内存区中。假设数组
;*  元素均为正数。
;*      例如, 将02H插入下面的数组中:
;*                01H,03H,04H,05H,....
;*      结果为    01H,02H,03H,04H,05H,....
;*      部分程序已经给出,其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中, 转换结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已经给出的一段源程序使其完整,填空处已
;*  经用横线标出, 每个空白一般只需要填一条指令或指令的一部分(指
;*  令助记符或操作数), 考生也可以填入功能相当的多条指令, 或删去
;*  BEGIN和END之间原有的代码并自行编程来完成要求的功能。
;*      对程序必须进行汇编,并与IO.OBJ链接产生PROG1.EXE执行文件,
;*  最终运行程序产生结果(无结果或结果不正确者均不得分)。

EXTRN LOAD:FAR,SAVE:FAR
N       EQU     10
DSEG    SEGMENT
MIN     DB      -1
SOURCE  DB      N DUP(?)
X       EQU     2           ; 插入的数
RESULT  DB      N DUP(0)
NAME0   DB      "INPUT1.DAT",0
NAME1   DB      "OUTPUT1.DAT",0
DSEG    ENDS

SSEG    SEGMENT STACK
        DB      256 DUP (?)
SSEG    ENDS

CSEG    SEGMENT
        ASSUME  CS:CSEG,SS:SSEG,DS:DSEG
START PROC FAR
PUSH DS
XOR AX,AX
PUSH AX
        MOV     AX,DSEG
MOV DS,AX
        MOV     ES,AX

LEA DX,SOURCE
LEA SI,NAME0
        MOV     CX,N
        CALL    LOAD
;   *** BEGIN ***
        LEA     BX,SOURCE
        MOV     SI,N-2
        ADD     BX,SI
        MOV     SI,0
        MOV     AL,X
LP:     cmp     al,[bx+si]
       ;CMP     __,[BX+SI]
        JGE     INS
        MOV     DL,[BX+SI]
        mov     [bx+si+1],dl
        dec     bx
       ;MOV     [BX+SI+1],___
       ;DEC     _____________
        JMP     LP
INS:    mov     [bx+si+1],al
       ;MOV     _________,AL
        CLD
        LEA     SI,SOURCE
        LEA     DI,RESULT
        MOV     CX,N
        rep     movsb
       ;___     MOVSB
;   *** END   ***
        LEA     DX,RESULT
        LEA     SI,NAME1
        MOV     CX,N
        CALL    SAVE
        RET
START ENDP
CSEG    ENDS
        END     START

input1.dat 内容如下：
01030405060708090A0B
output1.dat 内容应当如下：
01 02 03 04 05 06 07 08 09 0A

上机题之34
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 内存中连续存放着两个有
;*  符号字节数序列Ak和Bk(k=0,…,9)，求序列Ck，Ck= Ak×Bk（Ck
;*  以有符号字的形式按C0,…,C9 的顺序连续存放）。
;*      例如：
;*      序列Ak为80H,C0H,81H,00H,…；
;*      序列Bk为80H,C0H,81H,7FH,…。
;*      结果Ck为4000H,1000H,3F01H,0000H,…。
;*      部分程序已给出，其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中，运算结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已给出的源程序使其完整 (空白已用横线
;*  标出, 每行空白一般只需一条指令，但采用功能相当的多条指令亦
;*  可)， 或删除BEGIN和END之间原有的代码并自行编程来完成要求的
;*  功能。
;*      对程序必须进行汇编， 并与IO.OBJ链接产生PROG1.EXE执行文
;*  件，最终运行程序产生结果(无结果或结果不正确者均不得分)。调
;*  试中若发现整个程序中存在错误之处，请加以修改。

           EXTRN      LOAD:FAR,SAVE:FAR
N          EQU        10
STAC      SEGMENT   STACK
           DB          128 DUP (?)
STAC      ENDS           
DATA     SEGMENT        
SOURCE   DB          N*2 DUP(?)
RESULT   DW          N DUP(0)
NAME0    DB          "INPUT1.DAT",0
NAME1    DB          "OUTPUT1.DAT",0
DATA     ENDS       
CODE     SEGMENT   
           ASSUME    CS:CODE, DS:DATA, SS:STAC
START     PROC       FAR
           PUSH      DS
           XOR       AX,AX
           PUSH      AX
           MOV       AX,DATA
           MOV       DS,AX
           LEA       DX,SOURCE        ; 数据区起始地址
           LEA       SI,NAME0         ; 原始数据文件名
           MOV       CX,N*2           ; 字节数
           CALL      LOAD             ; 从 "INPUT1.DAT"中读取数据
;  **** BEGIN ****                               
           mov       di,offset result
           mov       bx,0
          ;MOV       DI,_____________
          ;______________
           MOV       CX,N
PRO:       mov       al,source[bx+N]
           imul      source[bx]
          ;MOV       AL,______________
          ;_____     SOURCE[BX]
           MOV       [DI],AX
           add       di,2
          ;ADD       ________
           INC        BX
           dec       cx
          ;______________________
           JNZ        PRO
;  ****  END  ****       
           LEA        DX,RESULT         ; 结果数据区首址
           LEA        SI,NAME1          ; 结果文件名
           MOV        CX,N*2            ; 结果字节数
           CALL       SAVE              ; 保存结果到文件
         RET
START    ENDP
CODE     ENDS
END      START

input1.dat 内容如下：
80 C0 81 00 7F 40 3F 80 C0 81 80 C0 81 7F 81 C0 3F 7F 7F 64
output1.dat 内容应当如下：
00 40 00 10 01 3F 00 00 FF C0 00 F0 81 0F 80 C0
40 E0 64 CE

上机题之35
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 在递增的有序字节数组中
;*  删去一个指定的数组元素，该元素在程序的数据段中用符号常量X
;*  表示（在数组元素中只有一个这样的元素）。 为了保持原数组个
;*  数不变, 将数组的最后一个元素填0。假设数组元素均为正数。
;*      例如, 在下面的数组中删去数组元素03H
;*                01H,02H,03H,04H,05H....
;*      结果为    01H,02H,04H,05H,.........,00H
;*      部分程序已经给出,其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中, 转换结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已经给出的一段源程序使其完整,填空处已
;*  经用横线标出, 每个空白一般只需要填一条指令或指令的一部分(指
;*  令助记符或操作数), 考生也可以填入功能相当的多条指令, 或删去
;*  BEGIN和END之间原有的代码并自行编程来完成要求的功能。
;*      对程序必须进行汇编,并与IO.OBJ链接产生PROG1.EXE执行文件,
;*  最终运行程序产生结果(无结果或结果不正确者均不得分)。

EXTRN LOAD:FAR,SAVE:FAR
N       EQU     10
DSEG    SEGMENT
SOURCE  DB      N DUP(?)
X       EQU     3            ; 指定的删除元素
RESULT  DB      N DUP(0)
NAME0   DB      "INPUT1.DAT",0
NAME1   DB      "OUTPUT1.DAT",0
DSEG    ENDS

SSEG    SEGMENT STACK
        DB      256 DUP (?)
SSEG    ENDS

CSEG    SEGMENT
        ASSUME  CS:CSEG,SS:SSEG,DS:DSEG
START PROC FAR
PUSH DS
XOR AX,AX
PUSH AX
        MOV     AX,DSEG
MOV DS,AX
        MOV     ES,AX

LEA DX,SOURCE
LEA SI,NAME0
        MOV     CX,N
        CALL    LOAD
;   *** BEGIN ***
        CLD
        LEA     DI,SOURCE
        MOV     AL,X
        MOV     CX,N
        repne   scasb
       ;_____   SCASB
        MOV     SI,DI
        dec     di
        rep     movsb
       ;DEC     _____
       ;REP     _____
        mov     byte ptr [di],0
       ;MOV     BYTE PTR [DI],___
        LEA     SI,SOURCE
        LEA     DI,RESULT
        mov     cx,N
       ;_________________
        REP     MOVSB
;   *** END   ***
        LEA     DX,RESULT
        LEA     SI,NAME1
        MOV     CX,N
        CALL    SAVE
        RET
START ENDP
CSEG    ENDS
        END     START

input1.dat 内容如下：
0102030405060708090A
output1.dat 内容应当如下：
01 02 04 05 06 07 08 09 0A 00

　　本题重编程序思路也许更为简单，举例如下：
以下内容为程序代码:

;   *** BEGIN ***
        CLD
        lea     si,source
        lea     di,result
        mov     cx,N-1
        mov     al,x
loop1:  cmp     al,[si]
        je      loop2
        movsb
        loop    loop1
loop2:  inc     si
        REP     MOVSB
        mov     byte ptr [di],0h
;   *** END   ***

本文来源：https://shitiku.jxxyjl.com/dengjikaoshi/1401.html