计算机等级考试三级含金量|计算机等级考试三级PC上级题精选26-30

【shitiku.jxxyjl.com--等级考试】

上机题之26
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 内存中连续存放的二十
;*  个八位有符号数(补码)是由一个八位A/D转换器采集的双极性信
;*  号(Xn), 现要求对该信号作如下处理(处理后的信号记为Yn):
;*        a).    Yn= Xn+5           Xn<-5
;*        b).    Yn=   0           │Xn│<=5
;*        c).    Yn= Xn-5           Xn>5
;*      例如:
;*        Xn:  03H,FEH(-2),4EH,A2H(-94), ...
;*        Yn:  00H,00H,    49H,A7H(-89), ...
;*      部分程序已在PROG1.ASM中给出, 请填空BEGIN和END之间已给
;*  出的源程序使其完整(空白已用横线标出, 每行空白一般只需一条
;*  指令, 但功能相当的多条指令亦可)或删除BEGIN和END之间原有的
;*  代码并自行编写程序片段来完成要求的功能。
;*      原始数据由过程LOAD从文件INPUT1.DAT中读入SOURCE开始的内
;*  存单元中, 结果要求从RESULT开始存放, 由过程SAVE保存到文件
;*  OUTPUT1.DAT中。
;*      对程序必须进行汇编, 并与IO.OBJ链接产生PROG1.EXE 执行文
;*  件, 最终运行程序产生结果(无结果或结果不正确者均不得分)。

           EXTRN      LOAD:FAR,SAVE:FAR

N          EQU        20
DELTA      EQU        5

STAC       SEGMENT    STACK
           DB         128 DUP (?)
STAC       ENDS

DATA       SEGMENT
SOURCE     DB         N   DUP(?)
RESULT     DB         N   DUP(0)
NAME0      DB         "INPUT1.DAT",0
NAME1      DB         "OUTPUT1.DAT",0
DATA       ENDS

CODE       SEGMENT
           ASSUME     CS:CODE, DS:DATA, SS:STAC
START      PROC       FAR
           PUSH       DS
           XOR        AX,AX
           PUSH       AX
           MOV        AX,DATA
           MOV        DS,AX

           LEA        DX,SOURCE   ; 数据区起始地址
           LEA        SI,NAME0    ; 原始数据文件名起始地址
           MOV        CX,N        ; 字节数
           CALL       LOAD        ; 从"input1.dat"中读取数据
;  **** BEGIN ****
           LEA        SI,SOURCE
           LEA        DI,RESULT
           mov        cx,N
           ;____________________
NEXT:      MOV        AL,[SI]
           CMP        AL,-DELTA
           jl         less
          ;J__        LESS
           CMP        AL,DELTA
           jg         great
          ;J__        GREAT
           MOV        AL,0
           JMP        STORE
GREAT:     SUB        AL,DELTA
           JMP        STORE
LESS:      ADD        AL,DELTA
STORE:     MOV        [DI],AL
           inc        di
           inc        si
           loop       next
          ;____________________
          ;____________________
          ;____________________
;  ****  END  ****
           LEA        DX,RESULT    ; 结果数据区首址
           LEA        SI,NAME1     ; 结果文件名起始地址
           MOV        CX,N         ; 字节数
           CALL       SAVE         ; 保存结果到"output1.dat"文件中
           RET
START      ENDP
CODE       ENDS
           END        START

input1.dat 内容如下：
01 03 FE 06 13 44 78 30 FC C5 92 C5 FE 04 57 61 79 4A 05 FC
output1.dat 内容应当如下：
00 00 00 01 0E 3F 73 2B 00 CA 97 CA 00 00 52 5C
74 45 00 00

上机题之27
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 内存中连续存放着两个无
;*  符号字节数序列Ak和Bk (k=0,…,9)，求序列Ck，Ck=Ak-Bk（Ck以
;*  有符号字的形式按C0,…,C9的顺序连续存放）。
;*      例如：
;*      序列Ak为30H,FFH,80H,FFH,…；
;*      序列Bk为00H,FFH,FFH,0AH,…。
;*      结果Ck为0030H,0000H,FF81H,FFF5H, …。
;*      部分程序已给出, 其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中，运算结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已给出的源程序使其完整 (空白已用横线
;*  标出，每行空白一般只需一条指令，但采用功能相当的多条指令亦
;*  可)， 或删除BEGIN和END之间原有的代码并自行编程来完成要求的
;*  功能。
;*      对程序必须进行汇编， 并与IO.OBJ链接产生PROG1.EXE执行文
;*  件, 最终运行程序产生结果(无结果或结果不正确者均不得分)。调
;*  试中若发现整个程序中存在错误之处，请加以修改。

          EXTRN      LOAD:FAR,SAVE:FAR
N         EQU         10
STAC      SEGMENT   STACK
           DB          128 DUP (?)
STAC        ENDS
DATA       SEGMENT
SOURCE     DB         N*2 DUP(?)
RESULT     DW         N DUP(0)
NAME0      DB         "INPUT1.DAT",0
NAME1      DB         "OUTPUT1.DAT",0
DATA       ENDS
CODE       SEGMENT
            ASSUME    CS:CODE, DS:DATA, SS:STAC
START     PROC       FAR
            PUSH      DS
            XOR       AX,AX
            PUSH      AX
            MOV       AX,DATA
            MOV       DS,AX
            LEA       DX,SOURCE         ; 数据区起始地址
            LEA       SI,NAME0          ; 原始数据文件名
            MOV       CX,N*2            ; 字节数
            CALL      LOAD              ; 从"INPUT1.DAT"中读取数据
;  **** BEGIN ****
            MOV       DI,OFFSET RESULT ; 结果从RESULT开始存放
            MOV       BX,0
            mov       cx,N
           ;________________
PRO:        MOV       AH,0
            MOV       AL,SOURCE[BX]     ; 序列Ak中的一个字节
            sub       al,source[bx+N]
           ;SUB       AL,_______________ ; Ck=Ak-Bk
            jnc       jump
           ;____      JUMP               ; 无借位转JUMP
            mov       ah,0ffh
           ;MOV       AH,_____           ; 有借位转换成有符号字（为负）
JUMP:       mov       [di],ax
           ;MOV       ____,AX
            ADD       DI,2
            INC       BX
            DEC       CX
            JNZ       PRO
;  ****  END  ****
            LEA       DX,RESULT         ; 结果数据区首址
            LEA       SI,NAME1          ; 结果文件名
            MOV       CX,N*2            ; 结果字节数
            CALL      SAVE              ; 保存结果到文件
          RET
START     ENDP
CODE      ENDS
END       START

input1.dat 内容如下：
FF 80 7F 00 7F 80 FF 80 81 00 FF FF 80 00 7F 00 00 81 FE FF
output1.dat 内容应当如下：
00 00 81 FF FF FF 00 00 00 00 80 00 FF 00 FF FF
83 FF 01 FF

上机题之28
以下内容为程序代码:

;*      请编制程序PROG1.ASM，其功能是:
;*      内存中共有30个字节型数据,找出其中的两个ASCII字符串并进
;*  行校验。欲寻找的ASCII字符串由13个字符组成: #(23H),7个ASCII
;*  字符,*(2AH),2个ASCII字符，回车符(0DH),换行符(0AH)。
;*      校验方法为: 对字符#及字符*之间的7个ASCII字符进行异或操
;*  作, 若异或操作结果的ASCII字符表示(异或操作结果高4位的ASCII
;*  字符表示在前, 低4位的ASCII字符表示在后)与原字符串中字符*之
;*  后的两个ASCII字符相同, 则将原字符串原样保存; 反之,则将原字
;*  符串中的所有字符(共13个)均用字符!(21H)代替。
;*      例如:
;*      内存中有 33H,35H,23H("#",第一个字符串开始),46H,41H,30H,
;*  2EH,34H,3DH,31H,2AH("*"),32H,31H,0DH,0AH,46H,23H("#",第二个
;*  字符串开始), 46H,41H,30H,2EH,34H,3DH,30H,2AH("*"),32H,31H,
;*  0DH,0AH,55H
;*      结果为   23H,46H,41H,30H,2EH,34H,3DH,31H,2AH("*"),32H,
;*  31H(校验正确,该字符串原样保持),0DH,0AH,21H,21H,21H,21H,21H,
;*  21H,21H,21H,21H,21H,21H,21H,21H(校验错, 整个字符串用字符"!"
;*  代替)
;*      部分程序已给出, 其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中。运算结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已给出的源程序使其完整(空白已用横线标
;*  出,每行空白一般只需一条指令, 但采用功能相当的多条指令亦可),
;*  或删除BEGIN和END之间原有的代码并自行编程来完成要求的功能。
;*      对程序必须进行汇编,并与IO.OBJ链接产生PROG1.EXE执行文件,
;*  最终运行程序产生结果(无结果或结果不正确者均不得分)。调试中
;*  若发现整个程序中存在错误之处, 请加以修改。

           EXTRN      LOAD:FAR,SAVE:FAR
N          EQU        26
STAC       SEGMENT    STACK
           DB         128 DUP (?)
STAC       ENDS
DATA       SEGMENT
SOURCE     DB         N+4 DUP(?)
RESULT     DB         N DUP(0)
HH         DB         2 DUP(0)
NAME0      DB         "INPUT1.DAT",0
NAME1      DB         "OUTPUT1.DAT",0
DATA       ENDS
CODE       SEGMENT
           ASSUME     CS:CODE, DS:DATA, SS:STAC
START      PROC       FAR
           PUSH       DS
           XOR        AX,AX
           PUSH       AX
           MOV        AX,DATA
           MOV        DS,AX
           LEA        DX,SOURCE          ; 数据区起始地址
           LEA        SI,NAME0           ; 原始数据文件名
           MOV        CX,N+4             ; 字节数
           CALL       LOAD               ; 从 "INPUT1.DAT"中读取数据
;  **** BEGIN ****
           MOV        SI,0
           MOV        DI,0
           MOV        BX,2               ; 两个ASCII字符串
REPEAT:    MOV        AH,0
SEARCH:    MOV        AL,SOURCE[SI]
           INC        SI
           CMP        AL,"#"
           jne        search
          ;___        SEARCH
           MOV        RESULT[DI],AL
           INC        DI
SEARCH1:   MOV        AL,SOURCE[SI]
           INC        SI
           cmp        al,"*"
          ;CMP        AL,___
           JE         ASCII
           MOV        RESULT[DI],AL
           INC        DI
           XOR        AH,AL
           jmp        search1
          ;JMP        _______
ASCII:     MOV        RESULT[DI],AL
           INC        DI
           PUSH       DI
           MOV        DI,0
           MOV        DH,2
           MOV        DL,AH                ; 异或结果暂存在DL中
           MOV        CL,4                 ; 先将异或结果高4位转换成ASDCII字
                                           ; 符
           SHR        AH,CL                ; 本行开始的4行语句将一个十六进制数
                                           ; 转换为ASCII码
CHANGE:   CMP        AH,10
           JL         ADD_0
           ADD        AH,"A"-"0"-10
ADD_0:     ADD        AH,"0"
           MOV        HH[DI],AH
           INC        DI
           DEC        DH
           JZ         EXT
           MOV        AH,DL                ; 再将异或结果低4位转换成ASDCII字符
           AND        AH,0FH
           JMP        CHANGE
EXT:       POP        DI
           MOV        AL,SOURCE[SI]
           MOV        RESULT[DI],AL
           INC        SI
           INC        DI
           MOV        AH,SOURCE[SI]
           MOV        RESULT[DI],AH
           INC        SI
           INC        DI
           MOV        DL,HH
           MOV        DH,HH+1
           CMP        AX,DX
           jne        err
          ;___        ERR
           MOV        AL,0DH              ; 校验正确
           MOV        RESULT[DI],AL
           INC        DI
           MOV        AL,0AH
           MOV        RESULT[DI],AL
           INC        DI
           JMP        LP
ERR:       SUB        DI,11               ; 校验错误
           MOV        AL,"!"
           mov        cx,13
          ;MOV        CX,___
COVER:     MOV        RESULT[DI],AL
           INC        DI
           LOOP       COVER
LP:        dec        bx
          ;________________
           JZ         EXIT
           JMP        REPEAT
EXIT:      NOP
;  ****    END  ****
           LEA        DX,RESULT          ; 结果数据区首址
           LEA        SI,NAME1           ; 结果文件名
           MOV        CX,N               ; 结果字节数
           CALL       SAVE               ; 保存结果到文件
           RET
START      ENDP
CODE       ENDS
           END        START

input1.dat 内容如下：
55 23 0A 40 0A 40 0A 40 00 2A 34 42 0D 0A 55 55 55 23 46 41 30 2E 33 3D 31 2A 32 36 0D 0A
output1.dat 内容应当如下：
21 21 21 21 21 21 21 21 21 21 21 21 21 23 46 41
30 2E 33 3D 31 2A 32 36 0D 0A
output1.hex 内容应当如下：
DEDEDEDEDEDEDEDEDEDEDEDEDEDCB9BECFD1CCC2CED5CDC9F2F5FF

上机题之29
以下内容为程序代码:

;*      请编制程序PROG1.ASM，其功能是:
;*      对内存中两个由7个ASCII字符组成的字符串进行如下操作:
;*      在原字符串之前加上字符#(23H); 在原字符串之后加上字符*
;*  (2AH)及另外两个ASCII字符, 这两个ASCII字符为原字符串中各字
;*  符(但不包括字符#和*)异或操作后的ASCII码(异或操作结果的高4
;*  位的ASCII码在前, 低4位的ASCII码在后); 最后加上回车符(0DH)
;*  及换行符(0AH)。
;*     例如:
;*     内存中有 46H,41H,30H,2EH,34H,3DH,31H(第一个ASCII字符串),
;*              46H,41H,30H,2EH,34H,3DH,30H(第二个ASCII字符串)
;*     结果为   23H("#"),46H,41H,30H,2EH,34H,3DH,31H,2AH("*"),
;*              32H,31H,0DH,0AH,23H,46H,41H,30H,2EH,34H,3DH,
;*              30H,2AH,32H,30H,0DH,0AH
;*      部分程序已给出, 其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中。运算结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已给出的源程序使其完整(空白已用横线标
;*  出,每行空白一般只需一条指令, 但采用功能相当的多条指令亦可),
;*  或删除BEGIN和END之间原有的代码并自行编程来完成要求的功能。
;*      对程序必须进行汇编,并与IO.OBJ链接产生PROG1.EXE执行文件,
;*  最终运行程序产生结果(无结果或结果不正确者均不得分)。调试中
;*  若发现整个程序中存在错误之处, 请加以修改。
 
           EXTRN      LOAD:FAR,SAVE:FAR
N          EQU        14
STAC       SEGMENT    STACK
           DB         128 DUP (?)
STAC       ENDS
DATA       SEGMENT
SOURCE     DB         N DUP(?)
RESULT     DB         N+12 DUP(0)
NAME0      DB         "INPUT1.DAT",0
NAME1      DB         "OUTPUT1.DAT",0
DATA       ENDS
CODE       SEGMENT
           ASSUME     CS:CODE, DS:DATA, SS:STAC
START      PROC       FAR
           PUSH       DS
           XOR        AX,AX
           PUSH       AX
           MOV        AX,DATA
           MOV        DS,AX
           LEA        DX,SOURCE          ; 数据区起始地址
           LEA        SI,NAME0           ; 原始数据文件名
           MOV        CX,N               ; 字节数
           CALL       LOAD               ; 从 "INPUT1.DAT"中读取数据
;  **** BEGIN ****
           MOV        SI,0
           MOV        DI,0
           MOV        BX,2               ; 两个ASCII字符串
REPEAT:    MOV        CX,7               ; 每个字符串由7个ASCII字符组成
           mov        al,"#"
          ;MOV        AL,___
           MOV        RESULT[DI],AL
           INC        DI
           mov        ah,0
          ;MOV        AH,___
CHAR:      MOV        AL,SOURCE[SI]
           MOV        RESULT[DI],AL
           INC        DI
           INC        SI
           XOR        AH,AL
           loop       char
          ;LOOP       ________
           mov        al,"*"
          ;MOV        AL,___
           MOV        RESULT[DI],AL
           INC        DI
           MOV        DH,2
           MOV        DL,AH               ; 异或结果暂存在DL中
           MOV        CL,4                ; 先将异或结果高4位转换成ASDCII字符
           SHR        AH,CL
CHANGE:    CMP        AH,10               ; 本行开始的4行语句将一个十六进制数
                                          ; 转换为ASCII码
           JL         ADD_0
           ADD        AH,"A"-"0"-10
ADD_0:     ADD        AH,"0"
           MOV        RESULT[DI],AH
           INC        DI
           DEC        DH
           JZ         EXT
           MOV        AH,DL               ; 再将异或结果低4位转换成ASDCII字符
           AND        AH,0FH
           JMP        CHANGE
EXT:       mov        al,0dh
          ;MOV        AL,___
           MOV        RESULT[DI],AL
           INC        DI
           mov        al,0ah
          ;MOV        AL,___
           MOV        RESULT[DI],AL
           INC        DI
           DEC        BX
           jz         exit
          ;JZ         ______
           JMP        REPEAT
EXIT:      NOP
;  ****    END  ****
           LEA        DX,RESULT          ; 结果数据区首址
           LEA        SI,NAME1           ; 结果文件名
           MOV        CX,N+12            ; 结果字节数
           CALL       SAVE               ; 保存结果到文件
           RET
START      ENDP
CODE       ENDS
           END        START

input1.dat 内容如下：
46 41 30 2E 33 3D 31 0A 40 0A 40 0A 40 00
output1.dat 内容应当如下：
23 46 41 30 2E 33 3D 31 2A 32 36 0D 0A 23 0A 40
0A 40 0A 40 00 2A 34 41 0D 0A

上机题之30
以下内容为程序代码:

;*      请编制程序PROG1.ASM, 其功能是: 内存中连续存放着16个十
;*  六位二进制数，在原16个数的第4和第5个数之间插入00FFH，在原
;*  16个数的第8和第9个数之间插入FF00H，在原16个数的第12和第13
;*  个数之间插入55AAH， 在原16个数的最后加入AA55H。将按上述方
;*  法插入4个数后得到的20个数存入内存中。
;*      例如：
;*      内存中有 1020H,2002H,3033H,4440H,5008H,…,8FF8H
;*  (共16个字)
;*      结果为   1020H,2002H,3033H,4440H,00FFH,5008H,…,8FF8H,
;*  AA55H（共20个字）
;*      部分程序已给出，其中原始数据由过程LOAD从文件INPUT1.DAT
;*  中读入SOURCE开始的内存单元中。运算结果要求从RESULT开始存放,
;*  由过程SAVE保存到文件OUTPUT1.DAT中。
;*      填空BEGIN和END之间已给出的源程序使其完整 (空白已用横线
;*  标出，每行空白一般只需一条指令，但采用功能相当的多条指令亦
;*  可),或删除BEGIN和END之间原有的代码并自行编程来完成要求的功
;*  能。
;*      对程序必须进行汇编， 并与IO.OBJ链接产生PROG1.EXE执行文
;*  件，最终运行程序产生结果(无结果或结果不正确者均不得分)。调
;*  试中若发现整个程序中存在错误之处，请加以修改。

           EXTRN      LOAD:FAR,SAVE:FAR
N          EQU        16
STAC       SEGMENT    STACK
           DB         128 DUP (?)
STAC       ENDS        
DATA       SEGMENT     
SOURCE     DW         N DUP(?)
INDATA     DW         0AA55H,55AAH,0FF00H,00FFH
RESULT     DW         N+4 DUP(0)
NAME0      DB         "INPUT1.DAT",0
NAME1      DB         "OUTPUT1.DAT",0
DATA       ENDS       
CODE       SEGMENT   
           ASSUME     CS:CODE, DS:DATA, SS:STAC
START      PROC       FAR
           PUSH       DS
           XOR        AX,AX
           PUSH       AX
           MOV        AX,DATA
           MOV        DS,AX
           LEA        DX,SOURCE          ; 数据区起始地址
           LEA        SI,NAME0           ; 原始数据文件名
           MOV        CX,N*2             ; 字节数
           CALL       LOAD               ; 从 "INPUT1.DAT"中读取数据
;  **** BEGIN ****
           MOV        SI,0
           mov        di,0
           ;_______________
           MOV        CX,4
           MOV        BX,8
CHAN:      MOV        AX,SOURCE[SI]
           mov        result[di],ax
          ;_______________________
           INC        SI
           inc        si
           inc        di
          ;_____________
          ;_____________
           INC        DI
           DEC        CX
           JZ         INSER1
           JMP        CHAN
INSER1:    PUSH       SI
           MOV        SI,BX
           MOV        AX,INDATA[SI-2]
           mov        result[di],ax
          ;MOV        RESULT[DI],__
           DEC        BX
           dec        bx
          ;_____________
           JZ         EXIT
           mov        cx,4
          ;MOV        CX,___
           POP        SI
           INC        DI
           inc        di
          ;_______________
           JMP        CHAN
EXIT:      POP        SI
;  ****  END  ****
           LEA        DX,RESULT         ; 结果数据区首址
           LEA        SI,NAME1           ; 结果文件名
           MOV        CX,(N+4)*2             ; 结果字节数
           CALL       SAVE              ; 保存结果到文件
           RET
START      ENDP
CODE       ENDS
           END        START

input1.dat 内容如下：
34 12 FF E0 0D 23 78 AC AE EA 15 86 F0 05 7F F7 11 FE DD 3E ED DD 33 55 CC CC 11 22 33 DC A0 0A
output1.dat 内容应当如下：
34 12 FF E0 0D 23 78 AC FF 00 AE EA 15 86 F0 05
7F F7 00 FF 11 FE DD 3E ED DD 33 55 AA 55 CC CC
11 22 33 DC A0 0A 55 AA

本文来源：https://shitiku.jxxyjl.com/dengjikaoshi/1356.html